Macro assistance thread

Forum for mod & macro requests and discussion

Moderator: Demon Hunters

User avatar
100
Lealla
Class Leader
Posts: 3797
Contact:

Macro assistance thread

Post#1 » Mon Mar 05, 2007 6:48 pm

Hi, folks. Thanks for the warm welcome to YaWA.

I thought I'd take a moment to let you all know that I have studied the macro system in WoW 2.0 extensively and am willing to volunteer my time to help anyone set up or debug macros. I'm still getting the hang of things in the guild, so if there's another "macro guy" or "macro gal", feel free to tell me to get lost. :evil:

Anyway, post any or all requests, questions, etc. in this thread and I will do my best to answer. Note: many kinds of macros that were common before 2.0 will not work at all anymore, so please understand that if I say it can't be done, I'm not trying to pick on you.

For some good offline reading, there are great macro resources in the UI & Macros forum for beginners and advanced users alike. See the Macro Intro & FAQ and the 2.x Changes - Concise List threads.

User avatar
Gadera
Posts: 1071
Contact:

Post#2 » Mon Mar 05, 2007 10:29 pm

Awesome! Thanks for the offer to contribute your know-how to helping others get their macros fixed or up-and-running. I don't need any help right now, but I will be more than happy to hit you up when I do.

Also, I haven't really had a chance to say this before, but welcome to YaWA!

Sidenote: Moved to technical and stickifiedroxorz
Image

User avatar
100
Lealla
Class Leader
Posts: 3797
Contact:

Post#3 » Fri Mar 09, 2007 8:26 pm

To spur discussion, here are some sample macros that I use or have developed for others.

2.1 updates in green.
2.3 updates in yellow.
2.3.2 updates in orange.

Super Trinket
This macro will activate your trinket(s) in one click, no matter what slot they are equipped in. Note that most DPS boosting trinkets have linked cooldowns such that only one can be active at a time. You can also throw in other booster abilities like Heroism or Arcane Power as desired.
2.3 change: /stopcasting is no longer required.

Code: Select all

#showtooltip
/use 13
/use 14
/cast Arcane Power


Trinket + Nuke
To add onto the above, you can also chain these trinkets into a spellcast. I have also added the correct code to suppress error sounds and messages resulting from any or all of these items/abilities being on cooldown.
2.3 change: /stopcasting is no longer required.

Code: Select all

#showtooltip Pyroblast
/console Sound_EnableSFX 0
/use 13
/use 14
/cast Arcane Power
/cast Presence of Mind
/console Sound_EnableSFX 1
/run UIErrorsFrame:Clear()
/cast Pyroblast


Trinket + Nuke with modifier
Okay, so you don't like all the error spam of the above macros. Well, if you don't mind holding a modifier key to trigger your uber power of leetness, try this instead. It'll just cast Pyroblast when you activate it normally, but burn trinkets/cooldowns when you hold the Shift key.
2.3 change: /stopcasting is no longer required, "modifier" abbreviated.

Code: Select all

#showtooltip Pyroblast
/cast [nomod:shift] Pyroblast
/stopmacro [nomod:shift]
/use 13
/use 14
/cast Arcane Power
/cast Presence of Mind
/cast Pyroblast


Fishing
For this one, simply substitute the name of your fishing pole for the one in the macro. The first click equips it, the second and subsequent clicks start fishing. You'll have to equip your old weapon manually, though.
2.1 change: shows fishing pole icon if not equipped, Fishing skill when equipped.

Code: Select all

#showtooltip
/equip [noequipped:Fishing Pole] Seth's Graphite Fishing Pole
/cast [equipped:Fishing Pole] Fishing


Super Bandage
Put your highest level bandage in the macro, of course. This will use it on yourself if you don't have a friendly target.
2.1 change: compressed conditionals, added "nodead" clause.

Code: Select all

#showtooltip
/use [help,nodead] [target=player] Heavy Netherweave Bandage


Cleanse, Dispel, Abolish, etc. on mouseover
This macro (sub your own curative spell) will cast Cleanse on the friendly target you are hovering your mouse over, and will cast it normally otherwise. Bind it to a convenient key and you can cure players without targeting them first.
2.1 change: compressed conditionals, added "nodead" clause.

Code: Select all

#showtooltip
/cast [target=mouseover,help,nodead] [] Cleanse


OMFG I'm gonna DIEEE
Okay, so you've got a Healthstone, some Charged Crystal Focuses (Foci?), some Nightmare Seeds, some Fel Blossoms, and who knows what other lifesaving items, but you can't spare an action button for all of them? Why not do it in one? List all of your items in the order of priority that you want to use them, and the macro will always pick the first one that's in your inventory and not on cooldown. You can even throw in a potion if you want, although that's on a different cooldown so I recommend using a separate macro.

Changes (not version specific): Added line to remove error spam.

Code: Select all

/use Master Healthstone
/use Charged Crystal Focus
/use Nightmare Seed
/use Fel Blossom
/use Whipper Root Tuber
/run UIErrorsFrame:Clear()


Paladin mount w/Crusader Aura
This one's a bit complicated. The basic idea is thus: if you're not mounted, cast Crusader Aura and your flying mount in one click. If you're mounted, cast Sanctity Aura (or your choice of combat aura) and dismount in one click. Hold Shift for Summon Charger (without changing auras), and Ctrl to use your flying/normal mount (without changing auras).
2.1 changes: completely rewrote
2.3 changes: /dismount goes last due to sequencing, removed /stopcasting, actually works better since auras don't toggle
2.3.2 changes: added forced cast to auras; this removes the problem of toggling off Crusader inadvertently.

Code: Select all

#showtooltip
/cast [indoors][combat] !Retribution Aura; [nomounted,nomod] !Crusader Aura; [mod:shift]Summon Charger; [mounted] !Retribution Aura
/use [nomod:shift,flyable,outdoors,nocombat] Golden Gryphon
/dismount


Paladin taunt
This one is fairly simple. If your target is friendly, cast RD on them. Otherwise, look for your target's target. If none of these are friendly, bring up the hand cursor to target it yourself. (Note: you can't test to see if your target's target is you or not. In this case, RD won't do anything and you'll get the hand cursor.) The basic purpose for this is, if you lose aggro in a fight, just hit the macro and you'll get it back.
2.1 changes: compressed conditionals, added "nodead", removed extra "targettargettarget" as it could cause confusion.

Code: Select all

#showtooltip
/cast [help,nodead] [target=targettarget,help,nodead] [] Righteous Defense


Crowd Control
This macro can be used to set your focus on your crowd control target so you don't have to remember which mob you're CC'ing. Obviously, substitute your spell of choice. How this works is: if you currently have a hostile, alive focus, and you activate the macro, you will cast the spell on that target. If you don't have a valid focus, you'll cast on your current target. If you hold Shift while activating the macro, your focus will be set to your current target. If you bind the macro to a key, you can use your mouse to select your focus target as well.
2.1 changes: compressed conditionals.

Code: Select all

#showtooltip
/focus [target=mouseover,harm,nodead,modifier:shift] mouseover; [harm,nodead,modifier:shift] target
/cast [target=focus,harm,nodead] [] Entangling Roots


Downranking spells
Addons can't automatically downrank spells anymore, but you can with modifier keys. Hold Shift to cast Rank 1, and Ctrl to cast Rank 2 (or sub your own ranks).

Code: Select all

#showtooltip Moonfire
/cast [modifier:shift] Moonfire(Rank 1); [modifier:ctrl] Moonfire(Rank 2); Moonfire


Nature's Swiftness + Healing Touch
This one will cast NS and HT in a single click. It also uses mouseover and self-targeting. I recommend you bind this to a separate key from HT or use a modifier to cast NS, or you'll get a lot of error spam.
2.1 changes: compressed conditionals, added "nodead", used alt for self-cast.
2.3 changes: /stopcasting no longer necessary.

Code: Select all

#showtooltip Healing Touch
/cast Nature's Swiftness
/cast [mod:alt,target=player] [target=mouseover, help,nodead] [help,nodead] [] Healing Touch


Druid All-Purpose Mount/Escape
This macro is the new "super" all-in-one mount/dismount/escape macro, picking the best mount/form for any given situation. Hold a modifier key to force your land mount in Outland.
2.1 changes: completely rewrote for new macro commands.
2.3 changes: /dismount no longer needed, form switching is now instantaneous, /cancelform moved to end, fixed for autorecast.
2.3.2 changes: no longer need noform conditionals, now instantly uses land mount from a form.

Code: Select all

#showtooltip
/cast [swimming] Aquatic Form; [indoors] Cat Form; [combat] Travel Form; [flyable,nomod] Flight Form
/cancelform
/use [noswimming,outdoors,nocombat,noflyable][mod] Reins of the Swift Stormsaber
Last edited by Lealla on Thu Jan 17, 2008 9:31 am, edited 6 times in total.

70
Ecnailla
Posts: 3624

Post#4 » Fri Mar 09, 2007 8:37 pm

I'll throw this one in for rogue's while grinding- I have had quite a boost in funds because of this one:

/cast Pick Pocket
/stopcasting
/cast Cheap Shot

Turn on autoloot and grind away on any mob that you can pick pocket. Also helps level up lockpicking b/c of boxes.


I guess these would work too -

/cast Sap
/stopcasting
/cast Pick Pocket


/cast Pick Pocket
/stopcasting
/cast Ambush


but I haven't tested them.

User avatar
100
Lealla
Class Leader
Posts: 3797
Contact:

Post#5 » Fri Mar 09, 2007 9:44 pm

Oh, right... the Pick Pocket macro. I don't use autoloot normally, due to the risk of forgetting about it when I'm grouped and pissing someone off, but there is a way to turn it on selectively. Here's the macro:

Code: Select all

#showtooltip Pick Pocket
/run SetAutoLootDefault(1)
/cast Pick Pocket
/in 1 /run SetAutoLootDefault(nil)


The trick to this is that you have to have the Chronos addon installed (from Cosmos) to get the "/in" command; it's not part of the default UI. Other addons may provide a similar feature. You can also add your Ambush, Cheap Shot, or whatever other attack command you want at the end.

User avatar
Context
Posts: 1324
Contact:

Post#6 » Mon Mar 12, 2007 5:10 pm

there's not like an "eat/drink" macro is there?

just frustrating on my hunter, lol
only mana dependent char i have, i constantly forget one the other.
just wondering, thanks :)
Image
Image
...have trigger, will travel...

User avatar
110
Elvenbane
Leader
Posts: 4481
Contact:

Post#7 » Mon Mar 12, 2007 5:27 pm

ya, it's called put them side by side on ur damn bars nub!
It's the thought that counts, not how many people die because of it.
Elvenbane#1520

User avatar
100
Lealla
Class Leader
Posts: 3797
Contact:

Post#8 » Mon Mar 12, 2007 6:58 pm

You can set up a macro to eat or drink. You can't tell the game to pick the "best" food in your inventory, but you can use fall through logic, since eating and drinking don't invoke the global cooldown. You can also eat and drink with the same click or keypress.

Basic version:

Code: Select all

/use Smoked Talbuk Venison
/use Filtered Draenic Water


Advanced version - put the food and drink you want to use first in the top of the macro. You only have 255 characters to work with, so you have to be selective.

Code: Select all

/use Blackened Basilisk
/use Buzzard Bites
/use Ravager Dog
/use Purified Draenic Water
/use Filtered Draenic Water
/use Footman's Waterskin

The first matching food/drink of each respective type will be used. You will, however, get UI errors from each action that doesn't occur (there are ways to disable this if desired). Also, you can't have the macro pick which one to use based on your current health or mana.
Image
Image

User avatar
Context
Posts: 1324
Contact:

Post#9 » Mon Mar 12, 2007 7:33 pm

thanks Lea :D

EB..die.
Image

Image

...have trigger, will travel...

User avatar
100
Lealla
Class Leader
Posts: 3797
Contact:

Post#10 » Tue Mar 20, 2007 12:50 pm

Here's another good one that was posted on the UI & Macros forum. It allows Warriors to combine Taunt and Intervene into a single action button.

Taunt/Intervene

Code: Select all

/cast [help,nodead] Intervene; [harm,nodead]Taunt


There's a more powerful version that allows you to Taunt or Intervene on mouseover, as well as get the targeting cursor for Intervene if no other criteria are met.

Code: Select all

/cast [target=mouseover,help,nodead] Intervene; [target=mouseover,harm,nodead] Taunt; [harm,nodead] Taunt; [target=none] Intervene


If you find that taunting your mouseover target is too unpredictable (I found that casting offensive spells in this manner can be a bit tricky and requires precise awareness of what unit your cursor is over), remove the "[target=mouseover,harm,nodead] Taunt;" clause.
Image

Image

70
Ecnailla
Posts: 3624

Post#11 » Tue Mar 20, 2007 1:33 pm

Curious, is there a way to cast
Vamp. touch (cast time),
Vamp. Emb. (instant),
SW:P (instant),
MB (cast time),
Fear (instant)
off one macro? I think the moves with cast times makes it impossible, but I’m not sure.


I have them all lined up (elven), but when grinding im lazy.

I figure I could at least cut it down to 3 buttons- VT > Macro up to MB>fear.


Also, I have seen a macro for warlocks that they can spam that will only cast life drain if it isn’t already active. This allows them to spam it without wasting mana. Can I do this with Mindflay?

User avatar
100
Lealla
Class Leader
Posts: 3797
Contact:

Post#12 » Tue Mar 20, 2007 5:31 pm

Ecnailla:

Your first example is simply a castsequence, as follows. The reset portion puts you back to the beginning of the sequence when you enter or leave combat or you switch targets. These kinds of macros look nice on paper, but in practice they can screw you up if you get too dependent on them and something goes wrong.

Code: Select all

/castsequence reset=target/combat Vampiric Touch, Vampiric Embrace, Shadow Word: Pain, Mind Blast, Psychic Scream


For the second, that's the [channeling] conditional that is true when you're channeling a spell. This only works for channeled spells, not spells with a cast time. It would look like:

Code: Select all

/cast [nochanneling] Mind Flay
Image

Image

User avatar
110
Elvenbane
Leader
Posts: 4481
Contact:

Post#13 » Tue Mar 20, 2007 5:46 pm

ooh sexy

Code: Select all

/castsequence Shadow Word:Pain(Rank 1), Shadow Word:Pain(Rank 1), Shadow Word:Pain(Rank 1), Shadow Word:Pain(Rank 1), Shadow Word:Pain


oO CT_Core chokes when i try to /castsequence
Last edited by Elvenbane on Tue Mar 20, 2007 5:52 pm, edited 1 time in total.
It's the thought that counts, not how many people die because of it.
Elvenbane#1520

70
Ecnailla
Posts: 3624

Post#14 » Tue Mar 20, 2007 5:52 pm

Talk about a boost in PVP dmg!

User avatar
110
Elvenbane
Leader
Posts: 4481
Contact:

Post#15 » Tue Mar 20, 2007 5:53 pm

ya... but it takes 5-6s to complete that sequence
It's the thought that counts, not how many people die because of it.
Elvenbane#1520

Return to “WoW Addon & Macro Discussion”

Who is online

Users browsing this forum: No registered users and 1 guest