Elvenbane's Priest Macros - 7.x

Forum for mod & macro requests and discussion

Moderator: Demon Hunters

User avatar
110
Elvenbane
Leader
Posts: 4481
Contact:

Elvenbane's Priest Macros - 7.x

Post#1 » Tue Aug 09, 2016 5:41 am

The purpose of these macros is to condense the number of physical keys you need to press by controlling which spell is cast via modifier (alt/shift/ctrl) and adding mouseover capabilities to all healing spells.

** Important **
Before using these macros make sure you unbind the Action Page 1 - 6 keys in your key bindings. If you don't, pressing any of the shift modified macros will cause you to change action page instead of casting the appropriate spell.

I've included the keys I have them bound to but you can use whatever.

  • Base Healing Macro
  • Offensive Macro for Healers
  • Crowd Control Macros
  • Dispel Macro
  • Shadow Macros
  • Holy Macros
  • Discipline Macros

Base Healing Macro

This is the base macro that all my healing macros are derived from.

Alt: Self Cast
Mouseover Friend: Cast on Mouseover
Target Friend: Cast on Target
Target Enemy Targeting Friend: Cast on Enemy's Target
None of the Above: Default casting behavior. This condition also serves to generate the correct tooltip.

Code: Select all

#showtooltip
/cast [mod:alt,@player] [@mouseover,help,nodead] [help] [@targettarget,help] [] SPELL


Offensive Macro for Healers

This macro is primarily for healers who want to play Disc but want to play it like a traditional healer. Basically allows you to dps while having fiendly players targeted or moused over.

Mouseover Enemy: Cast on Mouseover
Target Enemy: Cast on Target
Mouseover Friend Targeting Enemy: Cast on Friend's Target
Target Friend Targeting Enemy: Cast on Friend's Target
None of the Above: Default casting behavior. This condition also serves to generate the correct tooltip.

Code: Select all

#showtooltip
/cast [@mouseover,harm,nodead] [harm] [@mouseovertarget,harm] [@targettarget,harm] [] SPELL


CC Macros

Clear Focus (shift), Set/Shackle Focus (alt), Shackle Target

Code: Select all

#showtooltip
/focus [mod:alt,@focus,dead] [mod:alt,@focus,noexists]
/clearfocus [@focus,dead] [mod:alt,@focus,noexists] [mod:shift]
/cast [mod:alt,@focus,exists] [] Shackle Undead;


Clear Focus (shift), Set/Mind Control Focus (alt), Mind Control Target

Code: Select all

#showtooltip
/focus [mod:alt,@focus,dead] [mod:alt,@focus,noexists]
/clearfocus [@focus,dead] [mod:alt,@focus,noexists] [mod:shift]
/cast [mod:alt,@focus,exists] [] Mind Control;


Dispel Macro

I use BindPad for this and have it bound to `


` - Mass Dispel (alt), Dispel Magic (harm), Purify Disease (help, shadow), Purify (help)

Code: Select all

/stopcasting
/cast [mod:alt] !Mass Dispel; [@mouseover,harm,nodead] [harm] Dispel Magic; [spec:3,@mouseover,help,nodead] [spec:3] Purify Disease; [@mouseover,help,nodead] [] Purify;


Shadow

Image

#1 - Vampiric Touch (alt), Shadow Word: Pain

Code: Select all

#showtooltip
/cast [mod:alt,@mouseover,harm] [mod:alt] Vampiric Touch; [@mouseover,harm] [] Shadow Word: Pain;


#2 - Vampiric Embrace (shift or shift+alt), Shadow Word: Void (shift), Mind Sear (alt), Mind Flay

Code: Select all

#showtooltip
/cast [notalent:1/3,mod:shift] [talent:1/3,mod:shift,mod:alt] Vampiric Embrace; [talent:1/3,mod:shift] Shadow Word: Void; [mod:alt] Mind Sear; Mind Flay


#3 - Power Word: Shield (shift), Shadow Word: Death (alt), Mind Blast

Code: Select all

#showtooltip
/cast [mod:shift,@player] Power Word: Shield; [mod:alt,@mouseover,harm,nodead] [mod:alt] Shadow Word: Death;  Mind Blast


#4 - Shadowfiend (alt or shift), Void Eruption/Void Bolt

Code: Select all

#showtooltip
/cast [mod:alt/shift] Shadowfiend; [@mouseover,harm,nodead] [] Void Eruption


#5 - Silence (shift), Fade

Code: Select all

#showtooltip
/cast [mod:shift] Silence; Fade


DPS Potion (ctrl), Power Infusion/Shadow Crash (no-shift), Dispersion

Code: Select all

#showtooltip
/cancelaura [nomod] Dispersion
/cast [mod:ctrl] Draenic Intellect Potion; [nomod:shift,talent:6/1] Power Infusion; [nomod:shift,talent:6/2] Shadow Crash; Dispersion


Holy

Image

Note: alt click will cast the unmodified spell on yourself. ie Alt-1 = PoM on self

#1 - Leap of Faith (shift+alt), Circle of Healing (shift), Prayer of Mending

Code: Select all

#showtooltip
/cast [mod:shift,mod:alt,@mouseover,help] [mod:shift,mod:alt] Leap of Faith; [talent:7/3,mod:shift,@mouseover,help] [talent:7/3,mod:shift] Circle of Healing; [mod:alt,@player] [@mouseover,help] [help] [@targettarget,help] [] Prayer of Mending


#2 - Guardian Spirit (shift), Renew

Code: Select all

#showtooltip
/cast [mod:shift,@mouseover,help] [mod:shift] Guardian Spirit; [mod:alt,@player] [@mouseover,help] [help] [@targettarget,help] [] Renew


#3 - Binding Heal (nomod), Holy Word: Serenity

Code: Select all

#showtooltip
/cast [talent:5/2,nomod,@mouseover,help] [talent:5/2,nomod,help] [talent:5/2,nomod,@targettarget,help] [talent:5/2,nomod] Binding Heal; [mod:alt,@player] [@mouseover,help] [help] [@targettarget,help] [] Holy Word: Serenity;
/stopspelltarget


#4 - Holy Word: Sanctify (shift), Flash Heal

Code: Select all

#showtooltip
/cast [mod:shift] Holy Word: Sanctify; [mod:alt,@player] [@mouseover,help] [help] [@targettarget,help] [] Flash Heal


#5 - Symbol of Hope (shift), Divine Star/Halo

Code: Select all

#showtooltip
/cast [talent:4/3,mod:shift] [talent:4/3,talent:6/1] Symbol of Hope; [talent:6/2] Divine Star; [talent:6/3] Halo;


#6 - Divine Hymn (shift), Heal

Code: Select all

#showtooltip
/cast [mod:shift] Divine Hymn; [mod:alt,@player] [@mouseover,help] [help] [@targettarget,help] [] Heal


Num- (Number 4 on my Naga) - Desperate Prayer (ctrl), Angelic Feather (shift), Apotheosis (alt), Prayer of Healing

Code: Select all

#showtooltip
/cast [mod:ctrl,talent:2/3] Desperate Prayer; [mod:shift,talent:2/1] Angelic Feather; [talent:7/1,mod:alt] Apotheosis; [@mouseover,help] [] Prayer of Healing


Discipline

Image

Note: alt click will cast the unmodified spell on yourself. ie Alt-1 = Plea on self

#1 - Leap of Faith (shift+alt), DStar/Halo (shift), Plea

Code: Select all

#showtooltip
/cast [mod:shift,mod:alt,@mouseover,help] [mod:shift,mod:alt] Leap of Faith; [mod:shift,talent:6/2] Divine Star; [mod:shift,talent:6/3] Halo; [mod:alt,@player] [@mouseover,help] [help] [@targettarget,help] [] Plea


#2 - Pain Suppression (shift), Power Word: Shield

Code: Select all

#showtooltip
/cast [mod:shift,@mouseover,help] [mod:shift,help] [mod:shift,@targettarget,help] [mod:shift] Pain Suppression; [mod:alt,@player] [@mouseover,help] [help] [@targettarget,help] [] Power Word: Shield


#3 - Power Word: Solace (shift), Penance (alt), Shadow Word: Pain

Code: Select all

#showtooltip
/cast [talent:4/1,mod:shift,@mouseover,harm,nodead] [talent:4/1,mod:shift] Power Word: Solace; [talent:1/1,mod:alt,@mouseover,help,nodead] [mod:alt,@mouseover,harm,nodead] [mod:alt] Penance; [@mouseover,harm,nodead] [] Shadow Word: Pain


#4 - Power Word: Barrier (shift+alt), Schism (shift), Shadowfiend (alt), Smite

Code: Select all

#showtooltip
/cast [mod:shift,mod:alt] Power Word: Barrier; [talent:1/3,mod:shift,@mouseover,harm,nodead] [talent:1/3,mod:shift] Schism; [mod:alt,harm] [mod:alt,@targettarget,harm] [mod:alt] Shadowfiend; [@mouseover,harm,nodead] [] Smite;


#5 - Clarity of Will (shift), Shadow Mend

Code: Select all

#showtooltip
/cast [talent:6/1,mod:shift,@mouseover,help] [talent:6/1,mod:shift] Clarity of Will; [mod:alt,@player] [@mouseover,help] [help] [@targettarget,help] [] Shadow Mend


Num- (Number 4 on my Naga) - Power Infusion (ctrl), Angelic Feather (shift), Power Word: Radiance

Code: Select all

#showtooltip
/cast [mod:ctrl,talent:5/2] Power Infusion; [mod:shift,talent:2/1] Angelic Feather; [@mouseover,help] [] Power Word: Radiance
It's the thought that counts, not how many people die because of it.
Elvenbane#1520

Return to “WoW Addon & Macro Discussion”

Who is online

Users browsing this forum: No registered users and 2 guests

cron